COM object EvExporter

EvApplication > EvFileCollection > EvFile > EvExportersCollection > EvExporter

View the COM map and the COM summary.

Description

Export

Export(string FileNameAndPath)

Summary

Export the CSV output from the exporter to a specified file path.

Parameters

• FileNameAndPath
• Name of the file to export the exporter output.

Return

Whether successful.

Example

The EV file has two preconfigured exporters.

Option Explicit
' Start Echoview
Dim oEvApp: Set oEvApp = CreateObject("EchoviewCom.EvApplication")

' Open the Exporter sample EV file
Dim oEvFile: Set oEvFile = oEvApp.OpenFile ("YourEVfileURL.EV")

If oEvFile Is Nothing Then
    MsgBox "Failed to open EV file"
Else
   Dim vExporterCollection: Set vExporterCollection = oEvFile.Exporters
   MsgBox "Number of exporters in the EV file: "& vExporterCollection.Count
   
   'Finding the first item in the list
   Dim vExporteritem : Set vExporteritem = vExporterCollection.Item(0) 
   MsgBox "First exporter name is: "& vExporteritem.Name 
   
   'Finding the second exporter by name
   Dim vSecondExporter : Set vSecondExporter = vExporterCollection.FindByName("Sv integration domain regions")
   MsgBox "Second exporter name is: "& vSecondExporter.Name 
   
   'Delete second exporter
   vExporterCollection.Delete(vSecondExporter)
   MsgBox "Deleted second exporter, Number of exporters in the EV file is now: "& vExporterCollection.Count
   
   'Export from the first Exporter
   'Export the first ExporterSetings, Export type, and Notes
   vExporteritem.Export("C:\Data and EV files\AExport\FirstExporter.csv")
   vExporteritem.ExportSettings("C:\Data and EV files\AExport\FirstExporterSettings.csv")
   
   MsgBox "First exporter, Name, Type and notes : "& vExporteritem.Name &"  Export type enum is "& vExporteritem.ExportType &"  Notes  "& vExporteritem.Notes 
   
End If
MsgBox "Press Enter to end this example script, and close Echoview without saving."

 

See also: EvVariableAcoustic.AddExporter example.

ExportSettings

ExportSettings(string FileNameAndPath)

Summary

ExportSettings outputs a file that contains the exporter's properties as lists of tab-separated values. This is equivalent to the right-click menu item Export, Settings on the Dataflow window.

The header row is:

ObjectName PropertyName CurrentValue Units MinimumValue MaximumValue ValueOptions DefaultValue

Parameters

• FileNameAndPath
• Name and path for the output file.

Return

Whether successful.

Example

See Exporter example.

ExportType

(read-only) ExportType

Summary

Returns the EExportType enum for the export type of the exporter.

Parameters

None

Return

Whether successful.

Example

See Exporter example.

GetOperand

EvVariableBase GetOperand(Integer Index)

Summary

Get the variable used as Operand n in the exporter of interest. The method returns the variable object. See also the Console action Operands (note, the Console operand list index is handled differently).

Parameters

• Index
• The Index value for the operand. It is an integer and represents the number of the operand,
• For Operand 1 the index = 1.

Return

EvVariableBase object.

Example

See SetOperand example.

Name

string Name

Summary

Access the name of the exporter. Note, the use of Dynamic exporter property and a Dynamic name will lock Name property.

Parameters

None

Return

The return is the name of the exporter.

Example

See Exporter example.

Notes

string Notes

Summary

Get or add text from the Notes section of the exporter, as a string of characters.

Parameters

None

Return

The return is a string containing the exporter Notes text.

Example

See Exporter example.

SetOperand

boolean SetOperand (integer Index, EvVariableBase Variable)

Summary

Assign the specified variable (an EvVariableBase object) as Operand n. See also the Console action Operands (note, the Console operand list index is handled differently).

Parameters

• Index
• The Index value for the operand. It is an integer and represents the number of the operand,
• For Operand 1 the index = 1.
• Variable
• Specifies the variable to use as the operand. Variable is represented by an EvVariableBase object - most likely selected from the Variables collection.

Return

Whether successful.

Example

'-------------------------------------------------
'START SCRIPT exporter example
'-------------------------------------------------
Dim vEvApp: Set vEvApp = CreateObject("EchoviewCom.EvApplication")

'Specify an EV file.
Dim vEvFile: Set vEvFile = vEvApp.OpenFile("C:\Data and EV files\AutoOpen\YourEvFile.EV")

'Specify an two acoustic variables
Dim vSvVar: Set vSvVar = vEvFile.Variables.FindByName("Fileset1: Sv pings")
Dim vProcessedSvVar: Set vProcessedSvVar = vEvFile.Variables.FindByName("ProcessedDataSv")

'Create new multiple operand Measurements - EVD exporter, with Operand 1 as "Fileset 1: Sv raw pings T1"
'Exporter with multiple operands Measurements - EVD is supported by eExportTypeEvd = 10

Dim vNewExporter: Set vNewExporter = vSvVar.AddExporter(10)

'Add a second operand vProcessedSvVar as Operand 2
vNewExporter.SetOperand 2, vProcessedSvVar

Dim vOp1: Set vOp1= vNewExporter.GetOperand(1)
Dim vOp2: Set vOp2 = vNewExporter.GetOperand(2)

'Display the exporter name and the operands
MsgBox " Name of exporter" + vNewExporter.Name

MsgBox " First operand " + vOp1.Name

MsgBox " Second operand " + vOp2.Name

vEvFile.SaveAs("C:\Data and EV files\AExport\ExporterExample.EV")
vEvApp.CloseFile(vEvFile)
vEvApp.Quit